@ECHO OFF
REM ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM + For real installation, remove 'ECHO ' from SETUPMSI AND SETPMSP. +
REM + To do a reboot after installation, remove REM at the ':END'      +
REM + Please consult kav8.0_wsee-install_guide_en.pdf for              +
REM + install options.                                                 +
REM ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

SET INSTOS=
SET SETUPMSI=start /WAIT msiexec /i
SET SETUPMSP=start /WAIT msiexec /p
IF DEFINED ProgramFiles(x86) GOTO 64BIT

:32BIT
ECHO INSTALLING 32-Bit
SET INSTOS=x86
GOTO MAIN

:64BIT
ECHO INSTALLING 64-Bit
SET INSTOS=x64
GOTO MAIN

:MAIN
CALL :GETKEY
CALL :INSTWSEE
CALL :INSTCF
GOTO END

:GETKEY
FOR /F %%K IN ('dir /B /OGN %~dp0\KEY') DO SET KEYFILE=%~dp0KEY\%%K
GOTO :EOF

:INSTWSEE
ECHO Install KAV WSEE AV
%SETUPMSI% %~dp0%INSTOS%\server\kavws.msi ADDLOCAL=Oas,ScriptChecker,AKIntegration,PerfMonCounters,TrayApp,Shell PRESCAN=1 RUNRTP=1 ADDMSEXCLUSION=1 ADDKLEXCLUSION=1 RADMINEXCLUSION=0 LICENSEKEYPATH=%KEYFILE% CONFIGPATH=C:\WSEE8_deu\konfig\avp-server-konfig.xml /l*v kavfs.log /qn EULA=1
ECHO Install KAV WSEE MMC Console
%SETUPMSI% %~dp0%INSTOS%\client\kavwstools.msi /l*v kavtools.log /qn EULA=1
GOTO :EOF

:INSTCF
ECHO Installing Critical Fixes
FOR /F %%C IN ('dir /B /OGN %~dp0\CritFix\*_%INSTOS%.msp') DO %SETUPMSP% %~dp0CritFix\%%C /qn
GOTO :EOF

:END
REM WMIC OS Where Primary=TRUE Call Shutdown
REM WMIC OS Where Primary=TRUE Call Reboot
WMIC OS Where Primary=TRUE Call Reboot